[geany/geany] 87f578: Improve Docutils (and friends) support in Autotools
Matthew Brush
git-noreply at xxxxx
Mon Apr 28 01:04:39 UTC 2014
Branch: refs/heads/master
Author: Matthew Brush <matt at geany.org>
Committer: Matthew Brush <matt at geany.org>
Date: Mon, 28 Apr 2014 01:04:39 UTC
Commit: 87f57812586dc1045ff9e95874f908fd87307ab3
https://github.com/geany/geany/commit/87f57812586dc1045ff9e95874f908fd87307ab3
Log Message:
-----------
Improve Docutils (and friends) support in Autotools
* Add `--enable-html-docs` and `--enable-pdf-docs` arguments
(off by default)
* Add `RST2HTML`, `RST2LATEX` and `PDFLATEX` to override path to these
tools.
* Add HTML and PDF doc status messages to configure summary
Modified Paths:
--------------
configure.ac
m4/geany-docutils.m4
Modified: configure.ac
2 lines changed, 2 insertions(+), 0 deletions(-)
===================================================================
@@ -113,6 +113,8 @@ GEANY_I18N
GEANY_DATA_DIR=`eval echo ${datarootdir}/geany`
AC_SUBST([GEANY_DATA_DIR])
+# Documentation tools
+GEANY_CHECK_DOCUTILS
GEANY_CHECK_DOXYGEN
# Output
Modified: m4/geany-docutils.m4
62 lines changed, 62 insertions(+), 0 deletions(-)
===================================================================
@@ -0,0 +1,62 @@
+dnl GEANY_CHECK_DOCUTILS
+dnl Check for the tools used to generate documentation
+dnl
+AC_DEFUN([GEANY_CHECK_DOCUTILS],
+[
+ GEANY_CHECK_DOCUTILS_HTML
+ GEANY_CHECK_DOCUTILS_PDF
+])
+dnl
+dnl GEANY_CHECK_DOCUTILS_HTML
+dnl For HTML documentation generation
+dnl
+AC_DEFUN([GEANY_CHECK_DOCUTILS_HTML],
+[
+ AC_ARG_ENABLE([html-docs],
+ [AS_HELP_STRING([--enable-html-docs],
+ [generate HTML documentation using rst2html [default=no]])],
+ [geany_enable_html_docs="$enableval"],
+ [geany_enable_html_docs="no"])
+ AC_ARG_VAR([RST2HTML], [Path to Docutils rst2html executable])
+ AS_IF([test "x$geany_enable_html_docs" != "xno"],
+ [
+dnl TODO: try rst2html.py first
+ AS_IF([test -z "$RST2HTML"], [RST2HTML="rst2html"])
+ AC_PATH_PROG([RST2HTML], [$RST2HTML], [no])
+ AS_IF([test "x$RST2HTML" != "xno"],
+ [geany_enable_html_docs="yes"],
+ [test "x$geany_enable_html_docs" = "xyes"],
+ [AC_MSG_ERROR([Documentation enabled but rst2html not found])],
+ [geany_enable_html_docs="no"])
+ ])
+ AM_CONDITIONAL([WITH_RST2HTML], [test "x$geany_enable_html_docs" != "xno"])
+ GEANY_STATUS_ADD([Build HTML documentation], [$geany_enable_html_docs])
+])
+dnl
+dnl GEANY_CHECK_DOCUTILS_PDF
+dnl For PDF documentation generation
+dnl
+AC_DEFUN([GEANY_CHECK_DOCUTILS_PDF],
+[
+ AC_ARG_ENABLE([pdf-docs],
+ [AS_HELP_STRING([--enable-pdf-docs],
+ [generate PDF documentation using rst2latex and pdflatex [default=no]])],
+ [geany_enable_pdf_docs="$enableval"],
+ [geany_enable_pdf_docs="no"])
+ AC_ARG_VAR([RST2LATEX], [Path to Docutils rst2latex executable])
+ AC_ARG_VAR([PDFLATEX], [Path to pdflatex executable])
+ AS_IF([test "x$geany_enable_pdf_docs" != "xno"],
+ [
+ AS_IF([test -z "$RST2LATEX"], [RST2LATEX="rst2latex"])
+ AC_PATH_PROG([RST2LATEX], [$RST2LATEX], [no])
+ AS_IF([test -z "$PDFLATEX"], [PDFLATEX="pdflatex"])
+ AC_PATH_PROG([PDFLATEX], [$PDFLATEX], [no])
+ AS_IF([test "x$RST2LATEX" != "xno" -a "x$PDFLATEX" != "xo"],
+ [geany_enable_pdf_docs="yes"],
+ [test "x$geany_enable_pdf_docs" = "xyes"],
+ [AC_MSG_ERROR([PDF documentation enabled but rst2latex or pdflatex not found])],
+ [geany_enable_pdf_docs="no"])
+ ])
+ AM_CONDITIONAL([WITH_LATEXPDF], [test "x$geany_enable_pdf_docs" != "xno"])
+ GEANY_STATUS_ADD([Build PDF documentation], [$geany_enable_pdf_docs])
+])
--------------
This E-Mail was brought to you by github_commit_mail.py (Source: https://github.com/geany/infrastructure).
More information about the Commits
mailing list