[geany/geany] 595b44: Improve Doxygen support in Autotools build system

[Matthew Brush]

Branch:      refs/heads/master
Author:      Matthew Brush <matt at geany.org>
Committer:   Matthew Brush <matt at geany.org>
Date:        Sun, 27 Apr 2014 06:29:43 UTC
Commit:      595b4459843ad75b353fcb0c6b62f95dc21b2f8e
             https://github.com/geany/geany/commit/595b4459843ad75b353fcb0c6b62f95dc21b2f8e

Log Message:
-----------
Improve Doxygen support in Autotools build system

* Add `m4/geany-doxygen.m4` file
* Support `DOXYGEN` environment variable setting which Doxygen to use
* Support `--enable-api-docs` to activate building Doxygen docs
    (off by default)


Modified Paths:
--------------
    configure.ac
    m4/geany-doxygen.m4

Modified: configure.ac
2 lines changed, 2 insertions(+), 0 deletions(-)
===================================================================
@@ -113,6 +113,8 @@ GEANY_I18N
 GEANY_DATA_DIR=`eval echo ${datarootdir}/geany`
 AC_SUBST([GEANY_DATA_DIR])
 
+GEANY_CHECK_DOXYGEN
+
 # Output
 AC_CONFIG_FILES([
 		Makefile


Modified: m4/geany-doxygen.m4
24 lines changed, 24 insertions(+), 0 deletions(-)
===================================================================
@@ -0,0 +1,24 @@
+dnl GEANY_CHECK_DOXYGEN
+dnl Check for Doxygen availability to generate API docs
+dnl
+AC_DEFUN([GEANY_CHECK_DOXYGEN],
+[
+	AC_ARG_ENABLE([api-docs],
+			[AS_HELP_STRING([--enable-api-docs],
+					[generate API documentation using Doxygen [default=no]])],
+			[geany_with_doxygen="$enableval"],
+			[geany_with_doxygen="no"])
+
+	AC_ARG_VAR([DOXYGEN], [Path to Doxygen executable])
+
+	AS_IF([test "x$geany_with_doxygen" != "xno"],
+	[
+		AS_IF([test "x$DOXYGEN" != "x"],
+			[geany_doxygen_path="$DOXYGEN"], [geany_doxygen_path="doxygen"])
+		AC_PATH_PROG([DOXYGEN], [$geany_doxygen_path], [no])
+		AS_IF([test "x$DOXYGEN" != "xno"], [geany_with_doxygen=yes], [geany_with_doxygen=no])
+	])
+
+	AM_CONDITIONAL([WITH_DOXYGEN], [test "x$geany_with_doxygen" != "xno"])
+	GEANY_STATUS_ADD([Build API documentation], [$geany_with_doxygen])
+])



--------------
This E-Mail was brought to you by github_commit_mail.py (Source: https://github.com/geany/infrastructure).